Comment compter le nombre de lettres ou de chiffres dans une cellule Excel ?

Guide « 108 astuces pour grands débutants sur Excel ! » Offert
Booster votre productivité en téléchargeant gratuitement votre ebook PDF des meilleures astuces pour les débutants et les pros d'Excel
Excel formation - 00 Astuces - 100
 

Dans ce tutoriel, je vais vous montrer comment calculer le nombre de chiffres et de lettres contenus dans une cellule Excel.

Et pour finir, en fin de tutoriel, nous verrons également comment dénombrer le nombre de caractères spéciaux également contenus dans une cellule Excel.

 

Téléchargement

Vous pouvez télécharger le fichier d'exemple de cet article en cliquant sur le lien suivant :

This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.
 

 

Tutoriel Vidéo

 

1. Comment compter tous les caractères dans une cellule ?

Au cours de plusieurs tutoriels précédents, nous avons déjà pu être amenés à compter le nombre de lettres totales contenues dans une cellule Excel.

Pour cela, rien de plus simple, Excel propose justement une fonction dédiée, qui est la fonction NBCAR() :

 =NBCAR(texte) 

Dans cette fonction, l’argument texte correspond à la chaîne de caractères pour laquelle nous souhaitons dénombrer le nombre de caractères totaux.

Pour notre illustration, nous retrouvons une liste des mots de passe utilisés par des utilisateurs d’un site internet.

Pour compter le nombre de caractères total, nous utiliserons donc la formule suivante :

 =NBCAR(B9) 

Excel formation - compter nombre lettres ou chiffres - 01

Jusqu’ici, rien de compliqué, en revanche les choses vont se corser lorsque nous allons souhaiter dénombre non pas tous les caractères, mais uniquement les lettres ou les chiffres contenus dans une chaîne.

 

2. Comment compter les lettres dans une cellule ?

Maintenant, voyons comment compter les lettres contenues dans une cellule.

Ici, nous allons nous limiter à construire des formules n’utilisant que les possibilités offertes directement par Excel, ce qui va nous amener à créer des formules à rallonge… Nous pourrions simplifier l’utilisation de celles-ci en développant des fonctions personnalisées en VBA. Si vous souhaitez que je pousse le tutoriel jusque-là, n’hésitez pas à m’en faire part dans les commentaires de la chaîne YouTube.

Pour cela, nous allons toujours nous appuyer sur la fonction NBCAR(), mais dans laquelle nous allons devoir retraiter la chaîne étudiée.

En effet, nous allons la modifier légèrement, pour que la fonction NBCAR() puisse ignorer les chiffres contenus dans celle-ci.

En effet, étant donné que les mots de passe sont composés de lettres et de chiffres, si nous retirons tous les chiffres, il ne restera plus que des lettres.

Et pour effectuer ce retraitement, nous allons pouvoir nous appuyer sur la fonction SUBSTITUE() qui permet d’effectuer une modification sur une chaîne de caractères :

 =SUBSTITUE(texte;ancien_texte;nouveau_texte) 

Dans cette fonction, l’argument texte correspond à la chaîne que nous souhaitons modifier, ici la valeur de la cellule, ancien_texte correspond au caractère qui nous souhaitons modifier (pour commencer, le chiffre zéro) et enfin, nouveau_texte correspond au caractère par lequel nous allons souhaiter le remplacer (les doubles guillemets vides vont nous permettre de supprimer le caractère ancien_texte) :

 =SUBSTITUE(B9;0;"") 

Les zéros ont bien disparu de la chaîne :

Excel formation - compter nombre lettres ou chiffres - 02

Il ne reste plus qu’à encapsuler une autre fonction SUBSTITUE() en tant qu’argument texte, laquelle va permettre de supprimer les chiffres 1 :

  =SUBSTITUE(SUBSTITUE(B9;1;"");0;"") 

Puis de répéter l’opération jusqu’à supprimer tous les chiffres :

  =SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;9;"");8;"");7;"");6;"");5;"");4;"");3;"");2;"");1;"");0;"")  

Tous les chiffres ont bien disparu :

Excel formation - compter nombre lettres ou chiffres - 03

Nous pouvons maintenant compter le nombre de caractères que cela représente avec la fonction NBCAR() :

 =NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;9;"");8;"");7;"");6;"");5;"");4;"");3;"");2;"");1;"");0;""))  

Ce qui nous permet d’obtenir le nombre de lettres :

Excel formation - compter nombre lettres ou chiffres - 04

 

3. Comment compter les chiffres contenus dans une cellule ?

Maintenant que nous savons comment compter les lettres contenues dans une cellule, nous pouvons simplement compter le nombre de chiffres par différence avec le nombre de caractères total :

 =NBCAR(B9)-NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;9;"");8;"");7;"");6;"");5;"");4;"");3;"");2;"");1;"");0;""))  

Excel formation - compter nombre lettres ou chiffres - 05

Si vous souhaitez raccourcir la formule mise en place ici, sachez qu’il est possible de la convertir en formule matricielle.

Pour cela, nous commençons par l’encapsuler dans une fonction capable d’interpréter une matrice, comme la fonction SOMME() :

  =SOMME(NBCAR(B9)-NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;9;"");8;"");7;"");6;"");5;"");4;"");3;"");2;"");1;"");0;"")))  

Puis, nous modifions l’argument du deuxième NBCAR() afin que celui-ci puisse supprimer tous les caractères contenus dans une matrice, c’est-à-dire que nous y saisissons les 10 chiffres à supprimer entre crochets et séparés par des points-virgules :

  =SOMME(NBCAR(B9)-NBCAR(SUBSTITUE(B9;{0;1;2;3;4;5;6;7;8;9};""))) 

Cette formule est alors beaucoup plus simple, et le résultat est évidemment identique :

Excel formation - compter nombre lettres ou chiffres - 06

 

4. Comment compter le nombre de caractères spéciaux dans une cellule

Maintenant, nous allons pouvoir compliquer les choses en intégrant dans les mots de passe des caractères spéciaux !

En effet, nous ne pourrons plus nous contenter ici de simplement déduire le nombre de chiffres par différence :

Excel formation - compter nombre lettres ou chiffres - 07

Et c’est là que la dernière formule va bien nous aider.

Il suffit en effet de reprendre cette dernière, puis d’y ajouter les 26 lettres de l’alphabet :

 =SOMME(NBCAR(B9)-NBCAR(SUBSTITUE(B9;{0;1;2;3;4;5;6;7;8;9;"a";"z";"e";"r";"t";"y";"u";"i";"o";"p";"q";"s";"d";"f";"g";"h";"j";"k";"l";"m";"w";"x";"c";"v";"b";"n"};"")))  

Attention de bien saisir les lettres entre guillemets.

Ensuite, étant donné que la chaîne contenue dans la cellule B9 peut contenir aussi bien des lettres en majuscules que des lettres en minuscule, nous allons modifier l’argument texte pour n’en récupérer que des minuscules, grâce à la fonction MINUSCULE() :

 =SOMME(NBCAR(B9)-NBCAR(SUBSTITUE(MINUSCULE(B9);{0;1;2;3;4;5;6;7;8;9;"a";"z";"e";"r";"t";"y";"u";"i";"o";"p";"q";"s";"d";"f";"g";"h";"j";"k";"l";"m";"w";"x";"c";"v";"b";"n"};"")))  

Cette formule nous permet d’obtenir le nombre total de caractères de la cellule B9, hors caractères spéciaux.

Il ne nous restera alors plus qu’à le soustraire au nombre de caractères total de la cellule :

 =NBCAR(B9)-SOMME(NBCAR(B9)-NBCAR(SUBSTITUE(MINUSCULE(B9);{0;1;2;3;4;5;6;7;8;9;"a";"z";"e";"r";"t";"y";"u";"i";"o";"p";"q";"s";"d";"f";"g";"h";"j";"k";"l";"m";"w";"x";"c";"v";"b";"n"};"")))  

Excel formation - compter nombre lettres ou chiffres - 08

Ensuite, pour calculer le nombre de lettres, nous pouvons reprendre la formule utilisée au tout début de ce tutoriel, à laquelle nous viendrons déduire le nombre de caractères spéciaux que nous venons de relever ici :

=NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;9;"");8;"");7;"");6;"");5;"");4;"");3;"");2;"");1;"");0;""))-D9  

Et pour finir, nous obtiendrons le nombre de chiffres par différence entre le nombre total de caractères et la somme du nombre de caractères spéciaux et de lettres :

 =C9-D9-E9 

Excel formation - compter nombre lettres ou chiffres - 09

 

 



Articles qui pourraient vous intéresser

Comment savoir si une date tombe un week-end sur Excel ?
Comment compter le nombre de lettres ou de chiffres dans une cellule Excel ?
N’imbriquer pas les fonctions SI() sur Excel !
Comment calculer une moyenne avec un ou plusieurs critères sur Excel ?
Comment convertir des données en nombre ou en texte sur Excel ? Les fonctions N() et T()
Comment créer une référence automatiquement sur Excel ? La fonction DECALER()
Comment extraire les plus petites et plus grandes valeurs avec Excel ? Les fonctions PETITE.VALEUR() et GRANDE.VALEUR()
Comment mettre en place une référence dynamique ? La fonction INDIRECT() d’Excel
Comment calculer le PGCD et le PPCM (« Plus Grand Commun Diviseur » et « Plus Petit Commun Multiple ») sur Excel ?
Comment utiliser la fonction SOMMEPROD d’Excel
Comment nettoyer une chaîne de caractères - Supprimer les espaces indésirables et les caractères illisibles sur Excel ?
Comment compter le nombre de feuilles, de lignes ou de colonnes Excel ?

Contact - Plan du site - À propos - Contact

© Excelformation.fr 2018-2022 - Excel, simplement

Haut de la page

Excelformation.fr propose de nombreuses formations pratiques et gratuites sur Microsoft Excel : des cours pour apprendre à structurer et analyser les données, des tutos sur les fonctions avancées, les formules et les formules avancées d'Excel, les formules matricielles, les mise-en-formes conditionnelles, les graphiques Excel (xls, xlsx, xlsm,…). Des tutoriels pour apprendre à automatiser les tâches répétitives (via des macro-commandes en VBA) de vos classeurs Excel.